Before Povray 3.1 the only possibility to modify a pattern was the turbulence keyword. It added some randomness to the pattern and could be modified with the additional keywords octaves, omega and lambda.

turbulence 0.4

A similar effect is possible with the warp statement, namely the turbulence warp.

It works just like turbulence and has the same optional keywords. Anyway the effect is not identical although it is similar.

warp { turbulence 0.4 }

pigment {
  marble
  color_map { ... }

  scale 5
  warp { turbulence 0.4 }
  scale 0.2
}

pigment {
   marble
   color_map { ... }

   scale 0.2
   warp { turbulence 0.4 }
   scale 5
}

The repeat warp repeats a certain part of the pattern with a frequency and a direction specified with the vector that follows the repeat keyword. The vector has to lie in one of the axes.

warp { repeat x }

Changing the length of the repeat vector changes the size of the repeated part.

warp { repeat x*0.5 }

You can of course combine several repeat warps:

warp { repeat x }
warp { repeat y }

You can slightly change the repeated section with the optional offset keyword. The vector following that keyword specifies the direction and amount the pattern is moved with each repeat step.

warp { repeat x*0.5 offset y*0.25 }

The last thing about the repeat warp is the flip keyword. It is also followed by a vector, but this vector must only have components either 1 or 0. 1 means the every second repeated section is flipped around that axis. The fist section in positive direction is not flipped, while the first one in negative direction is.

warp { repeat x flip x }
warp { repeat y flip y }

Another warp type is the black_hole warp. It distorts the pattern around a certain point towards this point.

The first parameter following the black_hole keyword is the point the black hole is located at. The second is the radius.

warp { black_hole <0.0, 0.0, 0.0>, 0.8 }

With the optional inverse keyword, you can invert the effect of the warp, meaning that it pushes away the pattern from the center.

warp {
  black_hole <0, 0, 0>, 0.8
  inverse
}

You can also place several black holes without using several warps with help of the repeat keyword.

warp {
  black_hole <0.3, 0.3, 0>, 0.25
  strength 3
  inverse
  repeat x*0.7
}

If the repeat vector is not parallel to one of the axes, the black hole is repeated in several directions.

warp {
  black_hole <0.3, 0.3, 0>, 0.25
  strength 3
  inverse
  repeat <0.7, 1, 0>
}

Finally you can also vary the position of the repeated warps using turbulence.

warp {
  black_hole <0.3, 0.3, 0>, 0.25
  strength 3
  inverse
  repeat <0.7, 1, 0>
  turbulence <0.15, 0.4, 0>
}

When using repeated black hole warps, the warp has to be completely within one repeat segment. This also applies for turbulence meaning that the turbulated warp must have a correct position.

This picture illustrates this requirement, for details consult the documentation.

warp {
  displace {
    pigment {
      gradient y
      color_map {
        [0.5 color rgb <0, 0, 0> ]
        [0.5 color rgb <1, 0, 0> ]
      }
      scale 2
      translate -1.5*y
    }
  }
}

Using also other colors adds displacement in the other directions.

warp {
  displace {
    pigment {
      gradient y
      pigment_map {
        [0.5
          gradient x
          color_map {
            [0.0 color rgb <0, 0,   0> ]
            [1.0 color rgb <0, 0, 0.7> ]
          }
        ]
        [0.5 color rgb <1, 0, 0> ]
      }
      scale 2
      translate -1.5*y
    }
  }
}

warp {
  displace {
    pigment {
      cylindrical
      poly_wave 2
      color_map {
        [0.0 color rgb 0]
        [1.0 color rgb 1]
      }
      rotate 90*x
    }
    type 1
  }
}